openssh-5.1p1 configure failure

[Tim Rice]

On Wed, 25 Feb 2009, Basavaraj Dengi wrote:

> Looking at the config log, the problem is that,
> configure is not taking the selinux library path[even though I am providing
> it with -L option]
 
The way configure is currently written, --wtih-selinux=path is not possible.
Try the attached patch to configure.ac. You will need to regenerate configure
by running autoconf.

> attached is the config.log for your reference.
> 
> thanks for your time
> 
> regards
> basavaraj
> 

-- 
Tim Rice				Multitalents	(707) 887-1469
tim at multitalents.net
-------------- next part --------------
--- configure.ac.old	2008-07-09 04:07:19.000000000 -0700
+++ configure.ac	2009-02-25 13:49:15.293233057 -0800
@@ -3299,14 +3299,39 @@
 SELINUX_MSG="no"
 LIBSELINUX=""
 AC_ARG_WITH(selinux,
-	[  --with-selinux          Enable SELinux support],
+	[  --with-selinux[[=PATH]] Enable SELinux support (optionally in PATH)],
 	[ if test "x$withval" != "xno" ; then
 		save_LIBS="$LIBS"
+		save_LDFLAGS="$LDFLAGS"
+		save_CPPFLAGS="$CPPFLAGS"
+		if test -n "${withval}" && \
+		    test "x${withval}" != "xyes"; then
+			if test -d "${withval}/lib"; then
+				if test -n "${need_dash_r}"; then
+					LDFLAGS="-L${withval}/lib -R${withval}/lib ${LDFLAGS}"
+				else
+					LDFLAGS="-L${withval}/lib ${LDFLAGS}"
+				fi
+			else
+				if test -n "${need_dash_r}"; then
+					LDFLAGS="-L${withval} -R${withval} ${LDFLAGS}"
+				else
+					LDFLAGS="-L${withval} ${LDFLAGS}"
+				fi
+			fi
+			if test -d "${withval}/include"; then
+				CPPFLAGS="-I${withval}/include ${CPPFLAGS}"
+			else
+				CPPFLAGS="-I${withval} ${CPPFLAGS}"
+			fi
+		fi
 		AC_DEFINE(WITH_SELINUX,1,[Define if you want SELinux support.])
 		SELINUX_MSG="yes"
 		AC_CHECK_HEADER([selinux/selinux.h], ,
+		    CPPFLAGS="$save_CPPFLAGS"
 		    AC_MSG_ERROR(SELinux support requires selinux.h header))
 		AC_CHECK_LIB(selinux, setexeccon, [ LIBSELINUX="-lselinux" ],
+		    LDFLAGS="$save_LDFLAGS"
 		    AC_MSG_ERROR(SELinux support requires libselinux library))
 		SSHDLIBS="$SSHDLIBS $LIBSELINUX"
 		AC_CHECK_FUNCS(getseuserbyname get_default_context_with_level)